let $name:= request:get-parameter('name','')
let $sd :=/SequenceDiagram[@name =$name]
let $homesym :=' || '
let $leftsym := ' >> '
let $rightsym := ' << '
let $actors := $sd/cast/actor
let $nactors := count($sd/cast/actor)
let $width := concat(100  div $nactors,'%')
return 

<table border='1'>
<tr>{for $a in $actors return <th width='{$width}'  bgcolor='{$a/@color}'>{string($a/@name)}</th>}</tr>
{for $x in $sd/trace/*

 return
    <tr>
    {
    if (name($x)='action')
    then 
        let $p := index-of($actors/@name,$x/@at )
        return
           (  for $i in (1 to $p - 1) return <td/>,
              <td align='center'  bgcolor='{$actors[@name=$x/@at]/@color}'>
                       {if ($x/@url)
                        then <a href='{$x/@url}'  target='demo'>{string($x/@do)}</a>
                        else string($x/@do)
                       }
             </td>
           )
    else if (name($x)='message')
    then 
        let $pfrom := index-of($actors/@name,$x/@from )
        let $pto := index-of($actors/@name,$x/@to)
        let $pfirst := min (($pfrom,$pto))
        let $plast := max(($pfrom,$pto))
        let $ltor := $pfrom = $pfirst
        let $text := if ($ltor) then concat($leftsym,$x/@text,$leftsym) else concat($rightsym,$x/@text,$rightsym) 
        return

           (  for $i in (1 to $pfirst - 1) return <td/>,
               <td  align='center' colspan='{$plast - $pfirst + 1 }' bgcolor ='{$actors[@name=$x/@from]/@color}' >
                
                {$text}
                { if ($x/@url)
                  then <a href='{$x/@url}' target='demo'>Link </a>
                  else ()
                }
                 
              </td>,
             for $i in ($plast + 1 to $nactors) return <td/>
            )


    else ()
    }
   </tr>
  }             
</table>